procedure crplusbpmask_s(image)

### modified combinemasks.cl    
### L. Storrie-Lombardi  4 May 2001

###  Enter a list of the image numbers, e.g.
###  175
###  176
###  176  
###  Assume BPM directories are bpmXXX
###  BPM mask   bpmXXX/bpm_im1.pl  (1-8) 
###  CR mask    crmaskXXX_1.pl  (1-8) 
###  new mask   bpmXXX/bpmcr_im1.pl  (1-8) 

string  image   {prompt="Input image(s)"}
 
struct  *inimglist
 
begin
 
        string  imglist         # equals image
        string  infile          # temporary list for files
        string  img             # image name from fscan
        string  mask1,mask2     # input file names
        string  maskout         # output file name 
        string  hfile           # header file 
        string  express         # expression for imexpr 
        int     i               # counter 
 
        express="max(a,b)"
# Get query parameter
        imglist = image
 
# Expand file lists into temporary files.
        infile =  mktemp("tmp$mask")
        sections (imglist,option="root",>infile)
        inimglist = infile
 
# Loop through images
        while (fscan(inimglist,img) != EOF) {
 
           print("processing:  obj"//img," . . .")

        for (i=1; i < 9; i+=1) {
                hfile="obj"//img//".fits["//i//"]"
                mask1="crmask"//img//"_"//i//".pl"
                mask2="bpm"//img//"/bpm_im"//i//".pl"
                maskout="bpm"//img//"/bpmcr_im"//i//".pl"
               
                imexpr(express,maskout,mask1,mask2)
                hedit(hfile,"BPM",maskout,add-,delete-,ver-,show+,update+)
                hedit(maskout,"BPM",maskout,add-,delete-,ver-,show+,update+)

        }
}

end